apollo/game/build.gradle

description = 'Apollo Game'

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath group: 'com.moandjiezana.toml', name: 'toml4j', version: '0.7.1'
    }
}

ext.pluginsDir = "$projectDir/src/plugins"

apply plugin: 'kotlin'
apply from: 'plugins.gradle'

sourceSets {
    main {
        kotlin {
            exclude 'stub.kt'
        }
    }
}

dependencies {
    compile project(':cache')
    compile project(':net')
    compile project(':util')

    compile group: 'io.github.lukehutch', name: 'fast-classpath-scanner', version: '2.0.21'
    compile group: 'org.jetbrains.kotlin', name: 'kotlin-stdlib-jre8', version: "$kotlinVersion"
    compile group: 'org.jetbrains.kotlin', name: 'kotlin-compiler', version: "$kotlinVersion"

    testCompile "org.jetbrains.kotlin:kotlin-test-junit:$kotlinVersion"
}

task run(type: JavaExec, dependsOn: [classes, pluginClasses]) {
    FileCollection gameClasspath = sourceSets.main.runtimeClasspath + sourceSets.main.compileClasspath

    main = 'org.apollo.Server'
    classpath = gameClasspath
    jvmArgs = ['-Xmx1750M']
    workingDir = "$rootDir"
}